schedwhen

schedwhen — Ajoute un nouvel évènement de partition.

Description

Ajoute un nouvel évènement de partition.

Syntaxe

schedwhen ktrigger, kinsnum, kwhen, kdur [, ip4] [, ip5] [...]
schedwhen ktrigger, "insname", kwhen, kdur [, ip4] [, ip5] [...]

Initialisation

ip4, ip5, ... -- Equivalent à p4, p5, etc., dans une instruction i de partition.

Exécution

kinsnum -- numéro d'un instrument. Equivalent à p1 dans une instruction i de partition.

« insname » -- une chaîne de caractères (entre guillemets) représentant un instrument nommé.

ktrigger -- valeur de déclenchement pour le nouvel évènement.

kwhen -- date de début du nouvel évènement. Equivalent à p2 dans une instruction i de partition.

kdur -- durée de l'évènement. Equivalent à p3 dans une instruction i de partition.

schedwhen ajoute un nouvel évènement de partition. L'évènement n'est programmé que lorsque la valeur de taux-k ktrigger prend une valeur non nulle. Les arguments, options incluses, sont les mêmes que dans une partition. Le temps kwhen (p2) est mesuré à partir de l'instant de cet évènement.

Si la durée est nulle ou négative, le nouvel évènement est de type MIDI, et il hérite le sous-évènement de relachement (release) de l'instruction schedwhen.

[Note] Note

Noter que l'opcode schedwhen ne peut pas accepter de p-champs chaîne de caractère. Si vous devez passer des chaînes de caractère à l'instanciation d'un instrument, utilisez l'opcode scoreline ou scoreline_i.

Exemples

Voici une exemple de l'opcode schedwhen. Il utilise le fichier schedwhen.csd.

Exemple 481. Exemple de l'opcode schedwhen.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac           -iadc    ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o schedwhen.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; Initialize the global variables.
sr = 44100
kr = 44100
ksmps = 1
nchnls = 1

; Instrument #1 - oscillator with a high note.
instr 1
  ; Use the fourth p-field as the trigger.
  ktrigger = p4
  kinsnum = 2
  kwhen = 0
  kdur = p3

  ; Play Instrument #2 at the same time, if the trigger is set.
  schedwhen ktrigger, kinsnum, kwhen, kdur

  ; Play a high note.
  a1 oscils 10000, 880, 1
  out a1
endin

; Instrument #2 - oscillator with a low note.
instr 2
  ; Play a low note.
  a1 oscils 10000, 220, 1
  out a1
endin


</CsInstruments>
<CsScore>

; Table #1, a sine wave.
f 1 0 16384 10 1

; p4 = trigger for Instrument #2 (when p4 > 0).
; Play Instrument #1 for half a second, trigger Instrument #2.
i 1 0 0.5 1
; Play Instrument #1 for half a second, no trigger.
i 1 1 0.5 0
e


</CsScore>
</CsoundSynthesizer>


Voir Aussi

event, event_i, schedule, schedkwhen, schedkwhennamed, scoreline, scoreline_i

Crédits

Auteur : John ffitch
Université de Bath/Codemist Ltd.
Bath, UK
Novembre 1998

Exemple écrit par Kevin Conder.

Nouveau dans la version 3.491 de Csound

Basé sur un travail de Gabriel Maldonado